addPyToM2Function -- convenience function for adding value hooks

Usage:

addPyToM2Function(type, f, desc)
Inputs:
- type, a python object, a string, or a list, the type(s) to convert;
- f, a function, the function that will do the converting;
- desc, a string, passed to the Strategy option of addHook;

Description

Most of the hooks used by value have the same general format: if the python object has a particular type, then use a particular function to convert it to a corresponding Macaulay2 thing. This function simplifies the process of adding such a hook.

For example, suppose we would like to convert Fraction objects from the Python fractions module to QQ objects. Without adding a hook, value will convert these objects to RR objects.

i1 : fractions = import "fractions"

o1 = <module 'fractions' from '/usr/lib/python3.14/fractions.py'>

o1 : PythonObject of class module

i2 : x = fractions@@"Fraction"(2, 3)

o2 = 2/3

o2 : PythonObject of class fractions.Fraction

i3 : value x

o3 = .6666666666666666

o3 : RR (of precision 53)

So we write a function to do the conversion and then install the hook using addPyToM2Function.

i4 : toQQ = x -> value x@@"numerator" / value x@@"denominator";

i5 : addPyToM2Function("fractions.Fraction", toQQ, "Fraction -> QQ");

i6 : value x

     2
o6 = -
     3

o6 : QQ

i7 : hooks value

o7 = {0 => (value, PythonObject, Strategy => unknown -> PythonObject)                    }
     {1 => (value, PythonObject, Strategy => collections.abc.Callable -> FunctionClosure)}
     {2 => (value, PythonObject, Strategy => collections.abc.Mapping -> HashTable)       }
     {3 => (value, PythonObject, Strategy => collections.abc.Set -> Set)                 }
     {4 => (value, PythonObject, Strategy => collections.abc.Sequence -> Sequence)       }
     {5 => (value, PythonObject, Strategy => collections.abc.MutableSequence -> List)    }
     {6 => (value, PythonObject, Strategy => str -> String)                              }
     {7 => (value, PythonObject, Strategy => numbers.Complex -> CC)                      }
     {8 => (value, PythonObject, Strategy => numbers.Real -> RR)                         }
     {9 => (value, PythonObject, Strategy => numbers.Integral -> ZZ)                     }
     {10 => (value, PythonObject, Strategy => bool -> Boolean)                           }
     {11 => (value, PythonObject, Strategy => Fraction -> QQ)                            }

o7 : NumberedVerticalList

Ways to use addPyToM2Function:

addPyToM2Function(List,Function,String)
addPyToM2Function(PythonObject,Function,String)
addPyToM2Function(String,Function,String)

For the programmer

The object addPyToM2Function is a method function.

The source of this document is in /build/macaulay2-88fgJW/macaulay2-1.25.11+ds/M2/Macaulay2/packages/Python/doc.m2:471:0.