numericalIrreducibleDecomposition -- finds the irreducible components of the zero set of a system of polynomials

Usage:

numericalIrreducibleDecomposition (system)
Inputs:
- system, a list, a system of polynomials, with no more equations than indeterminates
Optional inputs:
- StartDimension => ..., default value -1, Option to specify the dimension to begin searching for positive dimensional components
- Verbose => ..., default value false, option to specify whether additional output is wanted
Outputs:
- a numerical variety, containing a witness set for each irreducible component
Consequences:
- This function calls cascade and factorWitnessSet.

Description

Given a list of generators of an ideal I, this function returns a NumericalVariety with a WitnessSet for each irreducible component of V(I).

i1 : R=CC[x11,x22,x21,x12,x23,x13,x14,x24];

i2 : system={x11*x22-x21*x12,x12*x23-x22*x13,x13*x24-x23*x14};

i3 : V=numericalIrreducibleDecomposition(system)
found 6 irreducible factors 

o3 = V

o3 : NumericalVariety

i4 : WitSets=V#5; --witness sets are accessed by dimension

i5 : w=first WitSets;

i6 : w.cache.IsIrreducible

o6 = true

In the above example we found three components of dimension five, we can check the solution using symbolic methods.

i7 : R=QQ[x11,x22,x21,x12,x23,x13,x14,x24];

i8 : system={x11*x22-x21*x12,x12*x23-x22*x13,x13*x24-x23*x14};

i9 : PD=primaryDecomposition(ideal(system))

o9 = {ideal (x13, x23, x11*x22 - x21*x12), ideal (x12, x22, x23*x14 -
     ------------------------------------------------------------------------
     x13*x24), ideal (x23*x14 - x13*x24, x21*x14 - x11*x24, x22*x14 -
     ------------------------------------------------------------------------
     x12*x24, x12*x23 - x22*x13, x11*x23 - x21*x13, x11*x22 - x21*x12)}

o9 : List

i10 : for i from 0 to 2 do print ("dim =" | dim PD_i | "  " | "degree=" | degree PD_i)
dim =5  degree=2
dim =5  degree=2
dim =5  degree=4

Ways to use numericalIrreducibleDecomposition:

numericalIrreducibleDecomposition(List)

For the programmer

The object numericalIrreducibleDecomposition is a method function with options.

The source of this document is in /build/macaulay2-88fgJW/macaulay2-1.25.11+ds/M2/Macaulay2/packages/PHCpack/PHCpackDoc.m2:857:0.

numericalIrreducibleDecomposition -- finds the irreducible components of the zero set of a system of polynomials

Description

See also

Ways to use numericalIrreducibleDecomposition:

For the programmer