Macaulay2 » Documentation
Packages » MatrixFactorizations :: inducedMap(ZZdFactorization,ZZdFactorization)
next | previous | forward | backward | up | index | toc

inducedMap(ZZdFactorization,ZZdFactorization) -- make the map of ZZ/d-graded factorizations induced at each term by the identity map

Description

Let $d$ be the value of the optional argument Degree, or zero, if not given. For each $i$, the terms $D_{i+d}$ and $C_i$ must be subquotients of the same ambient free module. This method returns the factorization map induced by the identity on each of these free modules.

If Verify => true is given, then this method also checks that these identity maps induced well-defined maps. This can be a relatively expensive computation.

We illustrate this method by inducing some of the natural inclusions and surjections induced by taking kernels/cokernels of morphisms of factorizations.

i1 : R = ZZ/101[a,b,c]

o1 = R

o1 : PolynomialRing
 
i2 : C = koszulMF({a,b,c}, a^3+b^3+c^3)

      4      4      4
o2 = R  <-- R  <-- R
                    
     0      1      0

o2 : ZZdFactorization
 
i3 : f = randomFactorizationMap(C, C, Cycle => true, InternalDegree => 1)

          4                                                           4
o3 = 0 : R  <------------------------------------------------------- R  : 0
               | 24a-36b-30c 0           0           0           |
               | -29c        24a-36b-30c 0           0           |
               | -29a        0           24a-36b-30c 0           |
               | 29b         0           0           24a-36b-30c |

          4                                                           4
     1 : R  <------------------------------------------------------- R  : 1
               | 24a-36b-30c 0           0           0           |
               | -29c        24a-36b-30c -29b        -29a        |
               | 0           0           24a-36b-30c 0           |
               | 0           0           0           24a-36b-30c |

o3 : ZZdFactorizationMap
 
i4 : isWellDefined coker f

o4 = true
 
i5 : (coker f).dd^2 == (a^3 + b^3 + c^3)*id_(coker f)

o5 = true
 
i6 : i1 = inducedMap(coker f, C)

                                                                                        4
o6 = 0 : cokernel | 24a-36b-30c 0           0           0           | <--------------- R  : 0
                  | -29c        24a-36b-30c 0           0           |    | 1 0 0 0 |
                  | -29a        0           24a-36b-30c 0           |    | 0 1 0 0 |
                  | 29b         0           0           24a-36b-30c |    | 0 0 1 0 |
                                                                         | 0 0 0 1 |

                                                                                        4
     1 : cokernel | 24a-36b-30c 0           0           0           | <--------------- R  : 1
                  | -29c        24a-36b-30c -29b        -29a        |    | 1 0 0 0 |
                  | 0           0           24a-36b-30c 0           |    | 0 1 0 0 |
                  | 0           0           0           24a-36b-30c |    | 0 0 1 0 |
                                                                         | 0 0 0 1 |

o6 : ZZdFactorizationMap
 
i7 : i2 = inducedMap(C, image f)

          4
o7 = 0 : R  <------------------------------------------------------- image | 24a-36b-30c 0           0           0           | : 0
               | 24a-36b-30c 0           0           0           |         | -29c        24a-36b-30c 0           0           |
               | -29c        24a-36b-30c 0           0           |         | -29a        0           24a-36b-30c 0           |
               | -29a        0           24a-36b-30c 0           |         | 29b         0           0           24a-36b-30c |
               | 29b         0           0           24a-36b-30c |

          4
     1 : R  <------------------------------------------------------- image | 24a-36b-30c 0           0           0           | : 1
               | 24a-36b-30c 0           0           0           |         | -29c        24a-36b-30c -29b        -29a        |
               | -29c        24a-36b-30c -29b        -29a        |         | 0           0           24a-36b-30c 0           |
               | 0           0           24a-36b-30c 0           |         | 0           0           0           24a-36b-30c |
               | 0           0           0           24a-36b-30c |

o7 : ZZdFactorizationMap
 
i8 : ker i1 == image i2

o8 = true

See also

Ways to use this method:

The source of this document is in /build/macaulay2-88fgJW/macaulay2-1.25.11+ds/M2/Macaulay2/packages/MatrixFactorizations/MatrixFactorizationsDOC.m2:4045:0.