Macaulay2 » Documentation
Packages » MatrixFactorizations :: RingMap ZZdFactorization
next | previous | forward | backward | up | index | toc

RingMap ZZdFactorization -- apply a ring map

Description

We illustrate the image of a ZZ/d-graded factorization under a ring map.

i1 : R = QQ[x,y,z]

o1 = R

o1 : PolynomialRing
 
i2 : S = QQ[s,t]

o2 = S

o2 : PolynomialRing
 
i3 : phi = map(S, R, {s, s+t, t})

o3 = map (S, R, {s, s + t, t})

o3 : RingMap S <-- R
 
i4 : Rf = R/(x^3+y^3+z^3)

o4 = Rf

o4 : QuotientRing
 
i5 : C = tailMF ideal vars Rf

      4      4      4
o5 = R  <-- R  <-- R
                    
     0      1      0

o5 : ZZdFactorization
 
i6 : D = phi C

      4      4      4
o6 = S  <-- S  <-- S
                    
     0      1      0

o6 : ZZdFactorization
 
i7 : isdFactorization D

              3     2        2     3
o7 = (true, 2s  + 3s t + 3s*t  + 2t )

o7 : Sequence
 
i8 : phi(potential C) == potential D

o8 = true
 
i9 : dd^D

          4                                            4
o9 = 1 : S  <---------------------------------------- S  : 0
               {5} | -s  -t2  s2+2st+t2 0         |
               {5} | -t  s2   0         s2+2st+t2 |
               {5} | s+t 0    s2        t2        |
               {6} | 0   -s-t -t        s         |

          4                                            4
     0 : S  <---------------------------------------- S  : 1
               {3} | -s2 -t2 s2+2st+t2 0          |
               {4} | -t  s   0         -s2-2st-t2 |
               {4} | s+t 0   s         -t2        |
               {4} | 0   s+t t         s2         |

o9 : ZZdFactorizationMap

When the ring map doesn't preserve homogeneity, the DegreeMap option is needed to determine the degrees of the image free modules in the factorizations.

i10 : R = ZZ/101[a..d]

o10 = R

o10 : PolynomialRing
 
i11 : S = ZZ/101[s,t]

o11 = S

o11 : PolynomialRing
 
i12 : phi = map(S, R, {s^4, s^3*t, s*t^3, t^4}, DegreeMap => i -> 4*i)

                   4   3      3   4
o12 = map (S, R, {s , s t, s*t , t })

o12 : RingMap S <-- R
 
i13 : C = koszulMF({a,b,c,d}, a^2+b^2+c^2+d^2)

       8      8      8
o13 = R  <-- R  <-- R
                     
      0      1      0

o13 : ZZdFactorization
 
i14 : D = phi C

       8      8      8
o14 = S  <-- S  <-- S
                     
      0      1      0

o14 : ZZdFactorization
 
i15 : isdFactorization D

              8    6 2    2 6    8
o15 = (true, s  + s t  + s t  + t )

o15 : Sequence
 
i16 : potential D == phi(potential C)

o16 = true

Caveat

Every term in the ZZ/d-graded factorization must be free or a submodule of a free module. Otherwise, use tensor(RingMap,ZZdFactorization).

See also

Ways to use this method:

The source of this document is in /build/macaulay2-88fgJW/macaulay2-1.25.11+ds/M2/Macaulay2/packages/MatrixFactorizations/MatrixFactorizationsDOC.m2:1901:0.